What's new

Discussion [Release] - Some awsome text mods

  • Thread starter QM Haackz
  • Start date
  • Views 609
Q

QM Haackz

Getting There
Messages
1,346
Reaction score
359
Here's just a couple of text mods i made for you guys, i know the majority of you can make these your self or 'claim' you can make them your self but what ev's. This post is mainly for the people who can't create these and to kind of make up for the very, very, very bad mistake i made back in the day xD
(for those who where around to remember xD)

Video

The ones used in the video
Code:
 //(Text, PosX, PosY, FontSize)
self thread RainText("vHaackzv2", 100, 100, 1.5);
self thread CylnText("vHaackzv2", 100, -100, 1.5);
self thread MoveText("vHaackzv2", -100, 100, 1.5);
self thread CyclText("vHaackzv2", -100, -100, 1.5);
self thread PulseText("vHaackzv2", -100, 0, 1.5, 2);
//(Text, PosX, PosY, FontSize, colourA, colourB)
self thread ColourText("vHaackzv2", 100, 0, 1.5, (0,1,0), (1,1,1));

Rain
Code:
Code:
RainText(Text, x, y, fs)
{
    c = 15;
    HUD = self createFontString("default", fs, self);
    for(;;)
    {
        if(c == 15)
        {
            HUD destroy();
            HUD = self createFontString("default", 1.5, self);
            HUD setPoint("CENTER", "CENTER", x, y);
            c = 0;
        }
        for(q=1;q<6;q++)
        {
            string = "";
            for(i=0;i<Text.size;i++)
            {
                o = q + i;
                for(a=5;a<16;a+=5)
                {
                    if(o > a && o < (a + 6))
                        o -= a;
                }
                string += "^" + o + Text[i]; 
            }
            HUD setText(string);
            wait .15;
        }
        c ++;
        wait .01;
    }
}
How to edit:
Code:
Speed - change the 'wait .15;' to a faster or slower (depends on preference)
Font - change the word "default" to your preferred font

CYLN
Code:
Code:
CylnText(Text, x, y, fs)
{
    c = 7;
    HUD = self createFontString("default", fs, self);
    for(;;)
    { 
        if(c == 7)
        {
            HUD destroy();
            HUD = self createFontString("default", 1.5, self);
            HUD setPoint("CENTER", "CENTER", x, y);
            c = 0;
        }
        for(i=0;i<Text.size;i++)
        {
            string = "";
            for(q=0;q<Text.size;q++)
            {
                if(i == q)
                    string += "^1" + Text[q];
                else
                    string += "^7" + Text[q];
            }
            HUD setText(string);
            wait .15;
        }
        c ++;
        wait .01;
    }
}
How to edit:
Code:
Font - change the word "default" to your preferred font
Colour - to change the red changer change the "^1" to one of the colour
Colours -
"^1" - Red
"^2" - Green
"^3" - Yellow
"^4" - Blue
"^5" - Cyan
"^6" - Rich Yellow
"^7" - white
"^0" - Black

Move
Code:
Code:
MoveText(Text, x, y, fs)
{
    i = Text.size;
    HUD = self createFontString("default", fs, self);
    HUD setPoint("CENTER", "CENTER", x, y);
    HUD setText(Text);
    for(;;)
    {
        HUD setPoint("CENTER", "CENTER", x + (i * 12), y, .4);
        wait .45;
        HUD setPoint("CENTER", "CENTER", x, y, .4);
        wait .5;
    }
}
How to edit:
Code:
Font - change the word "default" to your preferred font

CYCL
Code:
Code:
CyclText(Text, x, y, fs)
{
    HUD="";
    for(;;)
    { 
        HUD destroy();
        HUD = self createFontString("default", fs, self);
        HUD setPoint("CENTER", "CENTER", x, y);
        for(i=1;i<6;i++)
        {
            for(q=0;q<Text.size;q++)
            {
                string = "";
                for(p=0;p<Text.size;p++)
                {
                    if(p <= q)
                        string += "^" + i + Text[p];
                    else if(i == 1)
                        string += "^5" + Text[p];
                    else
                        string += "^" + (i - 1) + Text[p];
                }
                HUD setText(string);
                wait .15;
            }
        }
        wait .01;
    }
}
How to Edit:
Code:
Font - change the word "default" to your preferred font

Pulse
Code:
Code:
PulseText(Text, x, y, fs, fs2)
{
    HUD = self createFontString("default", fs, self);
    HUD setPoint("CENTER", "CENTER", x, y);
    HUD setText(Text);
    for(;;)
    {
        for(i=fs;i<=fs2;i+=.1)
        {
            HUD.fontScale = i;
            wait .01;
        }
        for(i=fs2;i>=fs;i-=.1)
        {
            HUD.fontScale = i;
            wait .01;
        }
        wait .01;
    }
}
How to Edit:
Code:
Font - change the word "default" to your preferred font

Colour Changing
Code:
Code:
ColourText(Text, x, y, fs, col, col2)
{
    HUD = self createFontString("default", fs, self);
    HUD setPoint("CENTER", "CENTER", x, y);
    HUD setText(Text);
    for(;;)
    {
        HUD fadeOverTime(1);
        HUD.color = col;
        wait 1;
        HUD fadeOverTime(1);
        HUD.color = col2;
        wait 1;
    }
}
How to Edit:
Code:
Font - change the word "default" to your preferred font
Speed - to change the speed you will have to edit 4 lines of code
 
*this HUD fadeOverTime(1);
        HUD.color = col;
*this wait 1;
*this HUD fadeOverTime(1);
        HUD.color = col2;
*this wait 1;
 
The lines marked with "*this" are the ones that use time, to change the speed just simply change the 1 on each of these lines to a time of your choice
1 = one second

Hope you enjoyed all these text mods and if i bother to make anymore i will be sure to update this post and post a message letting you know about the update. if you could leave me some feedback i will be great full and if you find any bugs please let me know as well.
Also if you want me to create more please let me know of any ideas you have :smile:
 
Last edited:
Z

Zero Two

Getting There
Messages
1,024
Reaction score
371
Nice, damn it. USE FRAPS!!! :o
 
E

Erza

Kieran Lavigne
Messages
236
Reaction score
109
Pretty cool. Nice, even though I won't use them. :wink:
 
Q

QM Haackz

Getting There
Messages
1,346
Reaction score
359
Pretty cool. Nice, even though I won't use them. :wink:
not just for use, you could also use parts of code for stuff you make youself :smile:
 
O

OfficialNeroModz

Enthusiast
Messages
272
Reaction score
48
I got most text mods from mw2 and put them on waw you skid :wink: jk but i did <3 an nice btw
 
D

DevilishMods

Enthusiast
Messages
152
Reaction score
29
Kewl beans! I will be using CYCL :biggrin:
 
Top Bottom